【VBA】ChatGPTを利用する

Open AIのアカウント登録

APIキー(secret key)の取得

準備

以下で紹介するコードは「VBA-JSON(JsonConverter.bas)」を使用してJSONデータをパースしています。よって「VBA-JSON(JsonConverter.bas)」が必要です。

「VBA-JSON(JsonConverter.bas)」の取得は以下の記事をご確認ください。
※以下の実施が必要です。
　・VBA-JSON(JsonConverter.bas)の取得
　・VBA-JSON(JsonConverter.bas)の微修正
　・参照設定の追加

VBAコード

ここでは例として
　・ChatGPTへ質問をして、回答を取得
します。
※今回は「VBAを学ぶメリットを教えてください。」と質問します。
※取得した回答をイミディエイトウィンドウへ出力します。
※エラーの場合はエラーメッセージをイミディエイトウィンドウへ出力します。

Option Explicit

Sub sample()
    
    Dim apiKey As String
    Dim question As String
    Dim url As String
    Dim requestBody As String
    Dim http  As Object
    Dim stream As Object
    Dim json As Variant
    Dim responseUtf8 As String
    
    'APIキー(secret key)
    apiKey = "XXXXXXXXXXXXXXXXXXXXXXXXXXXX"
    'ChatGPTへ渡す質問
    question = "VBAを学ぶメリットを教えてください。"
    
    'URL(APIエンドポイント)
    url = "https://api.openai.com/v1/chat/completions"
    'POSTリクエストのBody
    requestBody = "{""model"": ""gpt-3.5-turbo"",""messages"": [{""role"": ""user"", ""content"": """ & question & _
                  """}],""temperature"": 0.7}"
    
    Set http = CreateObject("WinHttp.WinHttpRequest.5.1")
    
    'HTTPリクエスト
    With http
        .Open "POST", url, False
        .setRequestHeader "Content-Type", "application/json"
        .setRequestHeader "Authorization", "Bearer " & apiKey
        .Send requestBody
    End With
    
    Set stream = CreateObject("ADODB.Stream")
    
    'HTTPレスポンス(=JSON)がバイナリデータのため、UTF-8へデコード
    'デコード結果(=JSON)を変数「responseUtf8」へ格納
    With stream
        .Type = 1 'Binary
        .Open
        .Write http.responseBody
        .Position = 0
        .Type = 2 'Text
        .Charset = "UTF-8"
        responseUtf8 = .ReadText
        .Close
    End With

    'デコード結果(=JSON)をパース
    Set json = JsonConverter.ParseJson(responseUtf8)
    
    '回答をイミディエイトウィンドウへ出力
    If VarType(json("error")) = vbEmpty Then
        Debug.Print json("choices")(1)("message")("content")
    Else
        Debug.Print json("error")("message")
    End If
    
    '後片付け
    Set http = Nothing
    Set stream = Nothing
    
End Sub

実行結果

VBAからChatGPTを利用できました。
※「VBAを学ぶメリットを教えてください。」を質問して回答を得ることができました。

参考

ChatGPTのAPIは有料ですが、5ドル分は無料です。
現時点の使用金額は以下で確認できます。