【VBA】ZIPファイルを解凍(展開)する

VBAで
　・ZIPファイルを解凍(展開)
できます！
※ここで紹介するのは「パスワード無しZIPファイル」の解凍(展開)方法です。

VBAから
　・Power Shellのコマンドレットを実行
することで実現します！
※コマンドレット「Expand-Archive」により実現します。

実行結果も取得できます！
※正常終了の場合、実行結果は「0」になります。
※異常終了の場合、実行結果は「1」になります。

ZIPファイル(パスワード付き)を解凍(展開)
することもできます！
詳細は以下の記事をご確認ください！

【VBA】ZIPファイル(パスワード付き)を解凍(展開)する【7-Zip】

【VBA】ZIPファイル(パスワード付き)を解凍(展開)するVBAコードです！【7-Zip】

はじめに
VBAコード
実行結果
参考①
参考②
参考③
参考④

はじめに

他のサイトではZIPファイルを
　・「CopyHere」メソッドなるものでで解凍(展開)する方法
が紹介されていたりしますが、こちらは動作保証されていません。
※公式サイトに動作保証していない旨が記載されています。

https://support.microsoft.com/ja-jp/topic/copyhere-%E3%83%A1%E3%82%BD%E3%83%83%E3%83%89%E3%81%8B%E3%82%89-zip-%E3%83%95%E3%82%A1%E3%82%A4%E3%83%AB%E3%82%92%E5%87%A6%E7%90%86%E3%81%99%E3%82%8B%E3%81%93%E3%81%A8%E3%81%AF%E3%81%A7%E3%81%8D%E3%81%BE%E3%81%9B%E3%82%93-a393a8b4-3330-5d88-c850-d634744fdb4a

動作保証されていない方法を採用するのは、やめておいた方がよいです。

VBAコード

ここでは例として
　・デスクトップ配下のZIPファイル「ken_all.zip」を
　・デスクトップ配下のフォルダ「output」配下へ解凍(展開)
します。

「ken_all.zip」は「郵便局のサイトからダウンロードした郵便番号データ(全国一括)」です。

Option Explicit

Sub execPsCommand()
    
    Dim zipFilePath As String
    Dim destFolderPath As String
    Dim psCommand As String
    Dim wsh As Object
    Dim result As Integer
    
    '解凍(展開)するZIPファイルを指定
    zipFilePath = "C:\Users\user\Desktop\ken_all.zip"
    
    '解凍(展開)先フォルダを指定
    destFolderPath = "C:\Users\user\Desktop\output"
    
    '実行するPowerShellのコマンドレットを組み立て
    psCommand = "powershell -NoProfile -ExecutionPolicy Unrestricted Expand-Archive -Path " & zipFilePath & " -DestinationPath " & destFolderPath & " -Force"
    
    Set wsh = CreateObject("WScript.Shell")
    
    'PowerShellのコマンドレットを実行
    result = wsh.Run(command:=psCommand, WindowStyle:=0, WaitOnReturn:=True)
    
    If (result = 0) Then
        MsgBox ("解凍(展開)が正常終了しました。")
    Else
        MsgBox ("解凍(展開)が異常終了しました。")
    End If
    
    '後片付け
    Set wsh = Nothing
    
End Sub

「解凍するZIPファイル」を指定します(12行目)。
「解凍先フォルダ」を指定します(15行目)。

実行するPower Shellのコマンドレットを組み立てます(18行目)。
※実行するPower Shellのコマンドレット「Expand-Archive」を組み立てます。
※オプション「-Force」により、解凍(展開)先フォルダに同名のファイルが存在する場合は上書きします。

ZIPファイルを解凍(展開)します(24行目)。
※Power Shellのコマンドレット「Expand-Archive」を実行します。

「Run」メソッドの引数「WindowStyle」に「0」を指定することで、PowerShell画面を非表示にできます(24行目)。
※「1(規定値)」を指定すると表示になります。

「Run」メソッドの引数「WaitOnReturn」に「True」を指定することで、同期実行になります(24行目)。
※「False(規定値)」を指定すると非同期実行になります。

ここでいう「同期実行」とは、
　・PowerShellのコマンドレットの処理完了後にVBAへ制御が返ってくるように実行
という意味です。
※PowerShellのコマンドレットの処理が完了するまでは、VBAの処理は停止して先に進みません。

PowerShellのコマンドレットが正常終了した場合、「戻り値(実行結果)」として「0」が返されます(26～29行目)。
※異常終了の場合は「1」が返されます。