【VBA】Webページ上の表をシートへ取り込む

例えばWeb上にある以下の表を…

VBAから
シートへ取り込めます！

VBAコード
実行結果
参考①
参考②
参考③

VBAコード

ここでは例として、以下のURLにある表をシート「sample」へ取り込みます。
第5回青鳩トレイルラン大会の男子30代Aの記録

Option Explicit

Sub sample()

    '取得したい表を持つURL
    Const TARGET_URL As String = "https://mulka2.com/lapcenter/lapcombat2/result-list.jsp?event=6047&file=3&class=7"
    
    With Worksheets("sample").QueryTables.Add(Connection:="URL;" + TARGET_URL, _
                                              Destination:=Range("B2"))
        '列幅を元の表と同じにする
        .AdjustColumnWidth = True
        '書式は設定しない
        .WebFormatting = xlWebFormattingNone
        '指定したテーブルのみ取得する
        .WebSelectionType = xlSpecifiedTables
        '1つ目の表を取得する
        .WebTables = 1
        '取得する
        .Refresh BackgroundQuery:=False
        '作成される「クエリと接続」を削除する
        .Delete
    End With

End Sub

「QueryTables.Add」で「QueryTableオブジェクト(＝クエリと接続)」を作成します(8～9行目)。

作成した「QueryTableオブジェクト(＝クエリと接続)」に
　・各種設定をして
　・取得を実行
します(11～19行目)。

「Destination」に「Range(“B2”)」を指定しているため、取り込んだ表はセル「B2」から設定されます(9行目)。

「指定したテーブルのみ取得」するために
　・「WebSelectionType」に「xlSpecifiedTables」
を指定しています(15行目)。

Webページ上の「1つ目の表」を取得するために
　・「WebTables」に「1」
を指定しています(17行目)。