【VBA】指定した範囲をCSVファイルへ出力する

VBAコード

ここでは例として、
　・シート「sample」のセル「B2」から続く一連の範囲を
　・デスクトップ配下へファイル「sample.csv」として出力
します。

Option Explicit

Sub sample()

    '出力するCSVファイル
    Const CSV_FILE As String = "C:\Users\user\Desktop\sample.csv"

    Dim targetRange As Range
    Dim wb As Workbook
    Dim fso As Object
    
    'CSVファイルへ出力する範囲を指定
    Set targetRange = Worksheets("sample").Range("B2").CurrentRegion
    
    '新規ブックを作成
    Set wb = Workbooks.Add
    
    'CSVファイルへ出力する範囲を新規ブックへコピー
    targetRange.Copy wb.Worksheets(1).Range("A1")
    
    Set fso = CreateObject("Scripting.FileSystemObject")
    
    '出力するCSVファイルが既に存在する場合は削除
    If fso.FileExists(CSV_FILE) Then
        fso.deleteFile CSV_FILE
    End If

    '新規ブックをCSVファイルとして出力
    wb.SaveAs Filename:=CSV_FILE, FileFormat:=xlCSV
    
    '新規ブックを保存せずに閉じる
    wb.Close SaveChanges:=False
    
    '後片付け
    Set fso = Nothing

End Sub

実行結果

指定した範囲をCSVファイルへ出力できました。

参考①

上記では「FileFormat:=」に「xlCSV」を指定することで、CSVファイルを出力しました。

指定する値を変更することで、様々な形式のファイルを出力できます。

詳細は公式サイトをご確認ください。

参考②

CSVファイルの読み込みもできます。

詳細は以下の記事をご確認ください。

参考③

CSVファイルとして出力する前に、データを並び替え(ソート)したほうが良いかもしれません。

データを並び替える(ソートする)方法は、以下の記事をご確認ください。

参考④

CSVファイルとして出力する前に、不要なデータを削除したほうが良いかもしれません。

オートフィルタを使用して不要なデータを削除できます。

詳細は以下の記事をご確認ください。