【VBA】折れ線グラフを作成する

VBAで
 ・折れ線グラフを作成
できます!

折れ線グラフ
折れ線グラフ

折れ線グラフ
 ・時系列での変化を確認する
ときに使用します!

PR

VBAコード

ここでは例として
 ・シート「sample」上にある「横浜市の犯罪件数」データを元に
 ・シート「sample」上に「折れ線グラフ(マーカー付き折れ線)」を作成
します。

「横浜市の犯罪件数」データ
「横浜市の犯罪件数」データ
Option Explicit

Sub sample()

    Dim ws As Worksheet
    Dim topPosition As Double
    Dim leftPosition As Double
    Dim shapeObj As shape
    
    'シートを指定
    Set ws = Worksheets("sample")
    
    '折れ線グラフを表示させる位置を取得
    With ws.Range("E3")
        leftPosition = .Left
        topPosition = .Top
    End With
    
    '折れ線グラフを作成
    Set shapeObj = ws.Shapes.AddChart2(Style:=227, _
                                       XlChartType:=xlLineMarkers, _
                                       Left:=leftPosition, _
                                       Top:=topPosition)
    
    '折れ線グラフの名前
    shapeObj.Name = "横浜市の犯罪件数"
    
    '折れ線グラフの設定
    With shapeObj.chart
        '元データ
        .SetSourceData Source:=ws.Range("B3").CurrentRegion
        'タイトル
        .ChartTitle.Text = "横浜市の犯罪件数"
        '横軸のラベルを縦書き
        .Axes(xlCategory).TickLabels.Orientation = xlTickLabelOrientationVertical
    End With

End Sub

「Worksheetオブジェクト」の「Shapes」プロパティにより、「Shapesオブジェクト」を取得します(20行目)。

「Shapesオブジェクト」の「AddChart2」メソッドにより、折れ線グラフを作成します(20~23行目)。
※手動で作成した場合と同じスタイルになるように、引数「Style」に「227」を指定します。
※グラフを「マーカー付き折れ線」にするために、引数「XlChartType」に「XlChartType列挙体」の「xlLineMarkers」を指定します。

※「AddChart2」メソッドにより「Shapeオブジェクト」を取得します。

グラフを削除する際に「名前を指定して削除」できるようにするため、棒グラフに名前を付けます(26行目)。

折れ線グラフの各種設定をします(29~36行目)。

PR

実行結果

折れ線グラフ(マーカー付き折れ線)を作成できました。

実行結果
実行結果
PR

参考①

グラフの削除もできます。

詳細は以下の記事をご確認ください。

PR

参考②

「横浜市の犯罪件数」の詳細は、神奈川県警察のサイトをご確認ください。

PR

参考③

上記で使用した以下の詳細は、公式サイトをご確認ください。

●「Worksheetオブジェクト」の「Shapes」プロパティ


「Shapesオブジェクト」の「AddChart2」メソッド


Shapeオブジェクト」


●XlChartType列挙体

PR

参考④

列挙体の詳細は、以下の記事をご確認ください。

タイトルとURLをコピーしました